Наработки для гуишников - Форум - Rewar.me — Фансайт Warcraft 3 Reforged (ex Ternox.com)

Наработки для гуишников

Ty3uK

Название: Пак наработок для гуи
Автор: Maxim Karelov aka Ty3uK
Вид наработки: Мапмейкерам
Тип исполнения: Jass 2
Тестовая карта: Присутствует
Минимальный патч: 1.24
Сложность импорта: Очень легко

Итак, в свет вышла еще одна УГ наработка от меня лично. Она позволяет ГУИшникам юзать для перемещения юнитов таймеры, а не периодические триггеры. Все функции очень просто вызываются и не вызывают утечек. В версии 1.0 присутствуют:

Движение дамми на определенное расстояние
Движение дамми до точки каста
Прыжок на определенное расстояние
Прыжок до точки каста

Code

function GetDistanceBetweenCoords takes real x1, real x2, real y1, real y2 returns real
       return SquareRoot((x2 - x1) * (x2 - x1) + (y2 - y1) * (y2 - y1))
endfunction

function MoveDummy_Timer takes nothing returns nothing
       local timer t = GetExpiredTimer()
       local integer hid = GetHandleId(t)
       local unit dummy = LoadUnitHandle(udg_Hashtable, hid, 0)
       local real angle = LoadReal(udg_Hashtable, hid, 1)
       local real distance = LoadReal(udg_Hashtable, hid, 2)
       local real speed = LoadReal(udg_Hashtable, hid, 3)
       local real d = LoadReal(udg_Hashtable, hid, 4)
       local real x = GetWidgetX(dummy) + speed * Cos(angle)
       local real y = GetWidgetY(dummy) + speed * Sin(angle)
       if d >= distance then
           if LoadBoolean(udg_Hashtable, hid, 5) then
               call RemoveUnit(dummy)
           else
               call PauseUnit(dummy, false)
           endif
           call FlushChildHashtable(udg_Hashtable, hid)
           call PauseTimer(t)
           call DestroyTimer(t)
       else
           call SetUnitPosition(dummy, x, y)
           call SaveReal(udg_Hashtable, hid, 4, d + speed)
       endif
       set dummy = null
       set t = null
endfunction

function MoveDummy takes unit dummy, real distance, real speed, boolean remove returns nothing
       local timer t = CreateTimer()
       local integer hid = GetHandleId(t)
       local unit caster = GetTriggerUnit()
       local real angle = Atan2(GetSpellTargetY() - GetWidgetY(caster), GetSpellTargetX() - GetWidgetX(caster))
       call SaveAgentHandle(udg_Hashtable, hid, 0, dummy)
       call SaveReal(udg_Hashtable, hid, 1, angle)
       call SaveReal(udg_Hashtable, hid, 2, distance)
       call SaveReal(udg_Hashtable, hid, 3, speed)
       call SaveBoolean(udg_Hashtable, hid, 5, remove)
       call PauseUnit(dummy, true)
       call TimerStart(t, .04, true, function MoveDummy_Timer)
       set caster = null
       set t = null
endfunction

function MoveDummyToTarget takes unit dummy, real speed, boolean remove returns nothing
       local timer t = CreateTimer()
       local integer hid = GetHandleId(t)
       local unit caster = GetTriggerUnit()
       local real angle = Atan2(GetSpellTargetY() - GetWidgetY(caster), GetSpellTargetX() - GetWidgetX(caster))
       call SaveAgentHandle(udg_Hashtable, hid, 0, dummy)
       call SaveReal(udg_Hashtable, hid, 1, angle)
       call SaveReal(udg_Hashtable, hid, 2, GetDistanceBetweenCoords(GetSpellTargetX(), GetWidgetX(caster), GetSpellTargetY(), GetWidgetY(caster)))
       call SaveReal(udg_Hashtable, hid, 3, speed)
       call SaveBoolean(udg_Hashtable, hid, 5, remove)
       call PauseUnit(dummy, true)
       call TimerStart(t, .04, true, function MoveDummy_Timer)
       set caster = null
       set t = null
endfunction

function TossUnit_Timer takes nothing returns nothing
       local timer t = GetExpiredTimer()
       local integer hid = GetHandleId(t)
       local unit u = LoadUnitHandle(udg_Hashtable, hid, 0)
       local real angle = LoadReal(udg_Hashtable, hid, 1)
       local real distance = LoadReal(udg_Hashtable, hid, 2)
       local real d = LoadReal(udg_Hashtable, hid, 3)
       local real z = LoadReal(udg_Hashtable, hid, 5)
       local real x = GetWidgetX(u)
       local real y = GetWidgetY(u)
       if d <= distance / 2  then
           set x = x + 10. * Cos(angle)
           set y = y + 10. * Sin(angle)
           set z = z + 25.
           call SetUnitPosition(u, x, y)
           call SetUnitFlyHeight(u, z, 0.)
       else
           set x = x + 10. * Cos(angle)
           set y = y + 10. * Sin(angle)
           set z = z - 25.
           call SetUnitPosition(u, x, y)
           call SetUnitFlyHeight(u, z, 0.)
       endif
       call SaveReal(udg_Hashtable, hid, 3, d + 10.)
       call SaveReal(udg_Hashtable, hid, 5, z)
       if z <= 0. then
           call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\Orc\\WarStomp\\WarStompCaster.mdl", x, y))
           call PauseTimer(t)
           call DestroyTimer(t)
           call PauseUnit(u, false)
           call FlushChildHashtable(udg_Hashtable, hid)
       endif
       set u = null
       set t = null
endfunction

function TossUnit takes unit u, real distance returns nothing
       local timer t = CreateTimer()
       local integer hid = GetHandleId(t)
       local unit caster = GetTriggerUnit()
       local real angle = Atan2(GetSpellTargetY() - GetWidgetY(caster), GetSpellTargetX() - GetWidgetX(caster))
       call SaveAgentHandle(udg_Hashtable, hid, 0, u)
       call SaveReal(udg_Hashtable, hid, 1, angle)
       call SaveReal(udg_Hashtable, hid, 2, distance)
       call SaveReal(udg_Hashtable, hid, 3, 10.)
       if UnitAddAbility(u, 'Amrf') then
           call UnitRemoveAbility(u, 'Amrf')
       endif
       call PauseUnit(u, true)
       call TimerStart(t, .01, true, function TossUnit_Timer)
       set caster = null
       set t = null
endfunction

function TossUnitToTarget takes unit u returns nothing
       local timer t = CreateTimer()
       local integer hid = GetHandleId(t)
       local unit caster = GetTriggerUnit()
       local real angle = Atan2(GetSpellTargetY() - GetWidgetY(caster), GetSpellTargetX() - GetWidgetX(caster))
       call SaveAgentHandle(udg_Hashtable, hid, 0, u)
       call SaveReal(udg_Hashtable, hid, 1, angle)
       call SaveReal(udg_Hashtable, hid, 2, GetDistanceBetweenCoords(GetSpellTargetX(), GetWidgetX(caster), GetSpellTargetY(), GetWidgetY(caster)))
       call SaveReal(udg_Hashtable, hid, 3, 10.)
       if UnitAddAbility(u, 'Amrf') then
           call UnitRemoveAbility(u, 'Amrf')
       endif
       call PauseUnit(u, true)
       call TimerStart(t, .01, true, function TossUnit_Timer)
       set caster = null
       set t = null
endfunction

Скачать

Функции вызываются очень просто:

1) Движение дамми на определенное расстояние:

Code

call MoveDummy(юнит, расстояние, скорость, удалять ли дамми в конце)

2) Движение дамми в точку каста:

Code

call MoveDummy(юнит, скорость, удалять ли дамми в конце)

3) Прыжок на определенное расстояние:

Code

call MoveDummy(юнит, расстояние)

4) Прыжок в точку каста:

Code

call MoveDummy(юнит)

Первыми двумя функциями можно двигать не только дамми, а кого угодно. Последними двумя можно кидать любого юнита.

Аниме - такая вещь, которая балансирует на грани "надоевшего" и "нового" из-за Наруто в основном. © [DUOS]
GUI Must Die v1.1 | Arena Multiboard

SirNikolas

Тип исполнения - Jass2, и при этом - перегрузка функций? O_o
И убери [cоde] из [с].

"I will make this the first approved cJass-only resource here on the Hive" - Bribe about ALL.

Ty3uK

SirNikolas, перегрузка? о_О

SirNikolas

Разные функции с одинаковыми именами. На cJASS реализуется следующим образом:

Code

define {
     abc(x, y, z) = abc_proto1(x, y, z)
     abc(x, y) = abc_proto2(x, y)//Или abc_proto1(x, y, 0)
     abc(x) = abc_proto3(x)//abc_proto1(x, 0, 0)
     abc() = abc_proto4()//abc_proto1(0, 0, 0)
}

"I will make this the first approved cJass-only resource here on the Hive" - Bribe about ALL.

Ty3uK

SirNikolas, увы, я не могу понять, где я использую одинаковые функи. Только когда запускаю таймер

SirNikolas

Quote (Ty3uK)

1) Движение дамми на определенное расстояние:

Code

call MoveDummy(юнит, расстояние, скорость, удалять ли дамми в конце)

2) Движение дамми в точку каста:

Code

call MoveDummy(юнит, скорость, удалять ли дамми в конце)

3) Прыжок на определенное расстояние:

Code

call MoveDummy(юнит, расстояние)

4) Прыжок в точку каста:

Code

call MoveDummy(юнит)

"I will make this the first approved cJass-only resource here on the Hive" - Bribe about ALL.

Ty3uK

SirNikolas, ох щит, перепутал же(((

Добавлено (26.12.11, 12:58)
---------------------------------------------

Функции вызываются очень просто:

1) Движение дамми на определенное расстояние:

Code

call MoveDummy(юнит, расстояние, скорость, удалять ли дамми в конце)

2) Движение дамми в точку каста:

Code

call MoveDummyToTarget(юнит, скорость, удалять ли дамми в конце)

3) Прыжок на определенное расстояние:

Code

call TossUnit(юнит, расстояние)

4) Прыжок в точку каста:

Code

call TossUnitToTarget(юнит)

Первыми двумя функциями можно двигать не только дамми, а кого угодно. Последними двумя можно кидать любого юнита.

Добавлено (27.12.11, 15:08)
---------------------------------------------

GUI Must Die! v1.1 или Наработки для гуишников v1.1

В новой версии:

Даммикаст на юнита
Даммикаст на точку
Даммикаст без цели
Возможность добавление другого эффекта в "Подбрасывание" (или наоборот, его исключение)

Вызов новых функций:

1) Даммикаст на юнита:

Code

call DummycastToTarget(кастер, 'равкод_дамми', 'равкод_способности', уровень_способности, цель, "ордер")

2) Даммикаст на точку:

Code

call DummycastToPoint(кастер, 'равкод_дамми', 'равкод_способности', уровень_способности, точка, "ордер")

3) Даммикаст без цели:

Code

call DummycastNoTarget(кастер, 'равкод_дамми', 'равкод_способности', уровень_способности, "ордер")

GUI Must Die v1.1

Сообщение отредактировал Ty3uK - Ср, 28.12.11, 17:31